AlgebraicAnalysis/Ore/RightLocalization.lean

AlgebraicAnalysis library · bbbbf3fc358ca8100b158cec4cf47f336ab70163

1 module
2 public import Mathlib.RingTheory.OreLocalization.Ring
3 public import Mathlib.Algebra.Ring.Opposite
4 public import Mathlib.Algebra.Group.Units.Opposite
5 
6 @[expose] public section
7 
8 /-!
9 # Right Ore localization
10 
11 The opposite-ring presentation of a right Ore localization and its
12 right-denominator clearing API. Extracted from Stafford38 commit
13 c8a513d553b24c7c08da82f496c44dbbaeb1f2fc.
14 -/
15 
16 namespace AlgebraicAnalysis.OreRightLocalization
17 
18 /-- The copy of `S` in the opposite ring. -/
19 def oppositeSubmonoid {R : Type u} [Monoid R] (S : Submonoid R) :
20     Submonoid Rᵐᵒᵖ where
21   carrier := {x | x.unop ∈ S}
22   one_mem' := S.one_mem
23   mul_mem' := by
24     intro a b ha hb
25     exact S.mul_mem hb ha
26 
27 /-- The right Ore localization of `R`, implemented as the opposite of
28 Mathlib's left Ore localization of `Rᵐᵒᵖ`. -/
29 abbrev RightOreLocalization (R : Type u) [Ring R] (S : Submonoid R)
30     [OreLocalization.OreSet (oppositeSubmonoid S)] :=
31   (OreLocalization (oppositeSubmonoid S) (Rᵐᵒᵖ))ᵐᵒᵖ
32 
33 /-- The numerator map into the right Ore localization. -/
34 def rightNumeratorRingHom
35     {R : Type u} [Ring R] {S : Submonoid R}
36     [OreLocalization.OreSet (oppositeSubmonoid S)] :
37     R →+* RightOreLocalization R S where
38   toFun r := MulOpposite.op
39     (OreLocalization.numeratorRingHom (S := oppositeSubmonoid S) (MulOpposite.op r))
40   map_one' := by
41     apply MulOpposite.unop_injective
42     exact RingHom.map_one _
43   map_zero' := by
44     apply MulOpposite.unop_injective
45     exact RingHom.map_zero _
46   map_add' a b := by
47     apply MulOpposite.unop_injective
48     exact RingHom.map_add _ _ _
49   map_mul' a b := by
50     apply MulOpposite.unop_injective
51     exact RingHom.map_mul _ (MulOpposite.op b) (MulOpposite.op a)
52 
53 /-- Every element of a right Ore localization has a right denominator in `S`
54 which is a unit and clears the fraction. -/
55 theorem rightOre_clear
56     {R : Type u} [Ring R] {S : Submonoid R}
57     [OreLocalization.OreSet (oppositeSubmonoid S)]
58     (q : RightOreLocalization R S) :
59     ∃ a s : R, s ∈ S ∧ IsUnit (rightNumeratorRingHom (S := S) s) ∧
60       q * rightNumeratorRingHom (S := S) s = rightNumeratorRingHom (S := S) a := by
61   generalize hx : q.unop = x
62   induction x using OreLocalization.ind with
63   | _ a s =>
64       refine ⟨a.unop, s.val.unop, s.property, ?_, ?_⟩
65       · exact isUnit_op.mpr (OreLocalization.numerator_isUnit
66           (R := Rᵐᵒᵖ) (S := oppositeSubmonoid S) s)
67       · apply MulOpposite.unop_injective
68         rw [show q = MulOpposite.op (a /ₒ s) by
69           apply MulOpposite.unop_injective
70           exact hx]
71         exact OreLocalization.mul_cancel (R := Rᵐᵒᵖ)
72           (S := oppositeSubmonoid S) (r := a) (s := s) (t := 1)
73 
74 
75 end AlgebraicAnalysis.OreRightLocalization
76