Stafford38/ChallengeBridge.lean

This project (Stafford38) · 1029fdb382eee06e7b59bcf32801f40931e2079a

1 module
2 public import Stafford38.ChallengeDefinitions
3 
4 @[expose] public section
5 
6 /-!
7 # Equivalences between the paper-form challenge statements and the Stafford statements
8 
9 `PaperTheorem_1_1` and `PaperCorollary_6_3` (in `Stafford38.ChallengeDefinitions`)
10 state Theorem 1.1 and Corollary 6.3 as printed.  This file proves that they follow
11 from the identity form `UniversalStatement`, the fixed-source form
12 `UniversalFixedSourceStatement` and the span form of cyclicity, so that both
13 solution routes can supply them:
14 
15 * `A_n = dA_n + FdA_n` iff `1 = dR + FdS` (`top_eq_sup_span_iff`);
16 * `IsLinearWeylCoordinate ℓ` iff `ℓ = Φ_g^{-1}(x₁)` for some `g ∈ Sp(2n, k)`
17   (`isLinearWeylCoordinate_iff`);
18 * `span {m} = ⊤` iff `M = mA` (`isCyclicModule_iff_span`).
19 -/
20 
21 namespace Stafford38Challenge
22 
23 universe u v
24 
25 /-- `Φ_g(u_i) = g(u_i)`. -/
26 theorem phiG_generator (k : Type*) [Field k] (n : ℕ) (g : Matrix.symplecticGroup (Fin n) k)
27     (i : PhaseVar n) :
28     phiG k n g (generator k n i) = linearImage k (g : Matrix (PhaseVar n) (PhaseVar n) k) i := by
29   simp [phiG, generator, Stafford.freeWeylGenerator, RingQuot.liftAlgHom_mkAlgHom_apply]
30 
31 /-- `A = dA + FdA` (right ideals) iff `1 = dR + FdS`. -/
32 theorem top_eq_sup_span_iff {A : Type*} [Ring A] (d F : A) :
33     (⊤ : Submodule Aᵐᵒᵖ A) = Submodule.span Aᵐᵒᵖ {d} ⊔ Submodule.span Aᵐᵒᵖ {F * d} ↔
34       ∃ R S : A, (1 : A) = d * R + F * d * S := by
35   constructor
36   · intro h
37     have h1 : (1 : A) ∈ Submodule.span Aᵐᵒᵖ {d} ⊔ Submodule.span Aᵐᵒᵖ {F * d} := h ▸ trivial
38     obtain ⟨y, hy, z, hz, hyz⟩ := Submodule.mem_sup.mp h1
39     obtain ⟨r, rfl⟩ := Submodule.mem_span_singleton.mp hy
40     obtain ⟨s, rfl⟩ := Submodule.mem_span_singleton.mp hz
41     exact ⟨r.unop, s.unop, hyz.symm⟩
42   · rintro ⟨R, S, h⟩
43     refine (eq_top_iff.mpr fun x _ => ?_).symm
44     have hx : x = d * (R * x) + F * d * (S * x) := by
45       rw [← mul_assoc, ← mul_assoc, ← add_mul, ← h, one_mul]
46     rw [hx]
47     exact Submodule.add_mem_sup
48       (Submodule.mem_span_singleton.mpr ⟨MulOpposite.op (R * x), rfl⟩)
49       (Submodule.mem_span_singleton.mpr ⟨MulOpposite.op (S * x), rfl⟩)
50 
51 /-- A linear symplectic coordinate is `Φ_g^{-1}(x₁) = Φ_{g⁻¹}(x₁)` for some
52 `ω`-preserving `g`. -/
53 theorem isLinearWeylCoordinate_iff (k : Type*) [Field k] (m : ℕ) (ell : WeylAlg k (m + 1)) :
54     Stafford38FixedSourceChallenge.IsLinearWeylCoordinate k m ell ↔
55       ∃ g : Matrix.symplecticGroup (Fin (m + 1)) k,
56         ell = phiG k (m + 1) g⁻¹ (x₁ k (Nat.succ_pos m)) := by
57   constructor
58   · rintro ⟨M, N, hM, -, hMN, -, rfl⟩
59     refine ⟨⟨M, SymplecticGroup.mem_iff.mpr hM⟩, ?_⟩
60     rw [phiG_generator, SymplecticGroup.coe_inv']
61     change _ = Stafford.linearCombination (M⁻¹) _ _
62     rw [Matrix.inv_eq_right_inv hMN]
63     rfl
64   · rintro ⟨g, rfl⟩
65     refine ⟨g, (g⁻¹ : Matrix.symplecticGroup (Fin (m + 1)) k),
66       SymplecticGroup.mem_iff.mp g.2, SymplecticGroup.mem_iff.mp (g⁻¹).2, ?_, ?_, ?_⟩
67     · change ((g * g⁻¹ : Matrix.symplecticGroup (Fin (m + 1)) k) :
68         Matrix (PhaseVar (m + 1)) (PhaseVar (m + 1)) k) = 1
69       rw [mul_inv_cancel]
70       rfl
71     · change ((g⁻¹ * g : Matrix.symplecticGroup (Fin (m + 1)) k) :
72         Matrix (PhaseVar (m + 1)) (PhaseVar (m + 1)) k) = 1
73       rw [inv_mul_cancel]
74       rfl
75     · rw [phiG_generator]
76       rfl
77 
78 /-- `M = mA` iff `span {m} = ⊤`. -/
79 theorem isCyclicModule_iff_span (A : Type u) (M : Type v) [Ring A] [AddCommGroup M]
80     [Module Aᵐᵒᵖ M] :
81     IsCyclicModule A M ↔ ∃ m : M, Submodule.span Aᵐᵒᵖ {m} = ⊤ := by
82   constructor
83   · rintro ⟨m, hm⟩
84     refine ⟨m, eq_top_iff.mpr fun x _ => ?_⟩
85     obtain ⟨a, rfl⟩ := hm x
86     exact Submodule.smul_mem _ _ (Submodule.mem_span_singleton_self m)
87   · rintro ⟨m, hm⟩
88     refine ⟨m, fun x => ?_⟩
89     have hx : x ∈ Submodule.span Aᵐᵒᵖ {m} := hm ▸ Submodule.mem_top
90     obtain ⟨a, rfl⟩ := Submodule.mem_span_singleton.mp hx
91     exact ⟨a.unop, rfl⟩
92 
93 /-- Theorem 1.1 as printed follows from the identity form and the fixed-source
94 form. -/
95 theorem paperTheorem_1_1_of (h1 : UniversalStatement.{u})
96     (h2 : Stafford38FixedSourceChallenge.UniversalFixedSourceStatement.{u}) :
97     PaperTheorem_1_1.{u} := by
98   intro k _ _ n d hd
99   obtain ⟨F, R, S, h⟩ := h1 k n d hd
100   refine ⟨⟨F, (top_eq_sup_span_iff d F).2 ⟨R, S, h⟩⟩, ⟨F, S, R, h⟩, fun hn => ?_⟩
101   obtain ⟨m, rfl⟩ : ∃ m, n = m + 1 := ⟨n - 1, by omega⟩
102   obtain ⟨ell, R', S', hell, h'⟩ := h2 k m d hd
103   obtain ⟨g, rfl⟩ := (isLinearWeylCoordinate_iff k m ell).1 hell
104   exact ⟨g, R', S', h'⟩
105 
106 /-- Corollary 6.3 as printed follows from the span form of cyclicity. -/
107 theorem paperCorollary_6_3_of
108     (h : ∀ (k : Type u) [Field k] [CharZero k] (n : ℕ) (M : Type v) [AddCommGroup M]
109       [Module (WeylAlg k n)ᵐᵒᵖ M] [Module.Finite (WeylAlg k n)ᵐᵒᵖ M],
110       Stafford38.TorsionCyclicity.IsRightTorsion (A := WeylAlg k n) (M := M) →
111         ∃ z : M, Submodule.span (WeylAlg k n)ᵐᵒᵖ {z} = ⊤) :
112     PaperCorollary_6_3.{u, v} := by
113   intro k _ _ n M _ _ _ hM
114   exact (isCyclicModule_iff_span _ _).2 (h k n M hM)
115 
116 #print axioms top_eq_sup_span_iff
117 #print axioms isLinearWeylCoordinate_iff
118 #print axioms paperTheorem_1_1_of
119 #print axioms paperCorollary_6_3_of
120 
121 end Stafford38Challenge
122